Imports Users in Active Directory to SQL Server

' Bind to RootDSE - this object is used to
' get the default configuration naming context
' e.g. dc=wisesoft,dc=co,dc=uk
set objRootDSE = getobject("LDAP://RootDSE")

' Root of search set to default naming context.
' e.g. dc=wisesoft,dc=co,dc=uk
' RootDSE saves hard-coding the domain.
' If want to search within an OU rather than the domain,
' specify the distinguished name of the ou. e.g.
' ou=students,dc=wisesoft,dc=co,dc=uk"
strRoot = objRootDSE.Get("DefaultNamingContext")

' Filter for user accounts - could be modified to search for specific users,
' such as those with mailboxes, users in a certain department etc.
strfilter = "(&(objectCategory=Person)(objectClass=User))"

' Attributes to return from the query
strAttributes = "sAMAccountName,userPrincipalName,givenName,sn," & _
"displayName,mail, " & _
"title,department," & _
"manager"

'Scope of the search. Change to "onelevel" if you didn't want to search child OU's
strScope = "subtree"

set cn = createobject("ADODB.Connection")
set cmd = createobject("ADODB.Command")

cn.open "Provider=ADsDSOObject;"
cmd.ActiveConnection = cn
cmd.commandtext = ";" & strFilter & ";" & _
strAttributes & ";" & strScope

set rs = cmd.execute

' Copy Field names to header row of worksheet

'Object for SQLSERVER
set cn2 = CreateObject("ADODB.Connection")

cn2.open "Provider=SQLNCLI;Server=SERVER_NAME;Database=DB_NAME;Trusted_Connection=yes;"

If rs.RecordCount > 0 then

rs.MoveFirst

cn2.execute "TRUNCATE TABLE UsersInAD"

While not rs.EOF

cn2.execute _
"INSERT INTO UsersInAD ([sAMAccountName], [userPrincipalName], [givenName], " & _
"[sn], [displayName], [mail], " & _
"[title], [department], [manager] ) " & _
"VALUES (" & _
"'" & rs.Fields("sAMAccountName") & "','" & rs.Fields("userPrincipalName") & "','" & rs.Fields("givenName") & "'," & _
"'" & rs.Fields("sn") & "','" & rs.Fields("displayName") & "','" & rs.Fields("mail") & "'," & _
"'" & rs.Fields("title") & "','" & rs.Fields("department") & "','" & rs.Fields("manager") & "'" & _
")"

rs.MoveNext
Wend

end If


rs.close
cn.close

set rs = Nothing
set cn = Nothing

cn2.Close
set cn2 = Nothing

PS: don't forget to adjust Table name, SQL Server Name, Database Name